QML-тип DockedPanel

Панель, которая пристыкована к краю элемента и расширяется от этого края. Подробнее...

Строка импорта: import Sailfish.Silica 1.0
Наследуется от: SilicaFlickable

Свойства

Методы

Подробное описание

Тип DockedPanel предоставляет контейнер, который пристыкован к краю компонента типа ApplicationWindow или Page и расширяется от этого края, чтобы отображать содержимое по требованию. Сдвиг DockedPanel (отображается поверх родительского элемента) в направлении к краю приведет к его закрытию.

Ниже приведен пример использования DockedPanel для размещения некоторых элементов управления в нижней части страницы Page:

 import QtQuick 2.2
 import Sailfish.Silica 1.0

 Page {
     SilicaFlickable {
         anchors {
             fill: parent
             bottomMargin: panel.margin
         }

         clip: panel.expanded
         contentHeight: column.height + Theme.paddingLarge

         Column {
             id: column
             spacing: Theme.paddingLarge
             width: parent.width

             Button {
                 text: panel.open ? "Hide controls" : "Show controls"
                 onClicked: panel.open = !panel.open
                 anchors.horizontalCenter: parent.horizontalCenter
             }
         }
     }

     DockedPanel {
         id: panel

         width: parent.width
         height: Theme.itemSizeExtraLarge + Theme.paddingLarge

         dock: Dock.Bottom

         Row {
             anchors.centerIn: parent
             Switch { icon.source: "image://theme/icon-m-shuffle" }
             Switch { icon.source: "image://theme/icon-m-repeat" }
             Switch { icon.source: "image://theme/icon-m-share" }
         }
     }
 }

Если панель пристыкована к краю компонента Page, следует продумать вопрос обрезки содержимого страницы с тем, чтобы содержимое страницы не отображалось под панелью. Если панель пристыкована к краю компонента ApplicationWindow, то достаточно будет установить значение свойства панели visibleSize равным свойству окна bottomMargin.

Описание свойств

animationDuration : int

Определяет время анимации открытия и закрытия панели.

Значение по умолчанию равно 500 мс.

dock : enumeration

В данном свойстве определено, к какому краю родительского элемента пристыкован DockedPanel. Свойство может принимать следующие значения:

  • 00a0Dock.Left — страница пристыкована к левому краю родительского элемента;
  • Dock.Top — страница пристыкована к верхнему краю родительского элемента;
  • Dock.Right — страница пристыкована к правому краю родительского элемента;
  • Dock.Bottom — страница пристыкована к нижнему краю родительского элемента.

Значение по умолчанию: Dock.Bottom.

[read-only] expanded : bool

Истинно, когда DockedPanel частично или полностью виден.

modal : bool

При истинном значении данного свойства панель DockedPanel становится модальной: все прочие элементы интерфейса затемняются, касания за пределами панели блокируются. Если панель немодальная, то касания за пределами панели закрывают ее.

[read-only] moving : bool

Истинно в момент открытия или закрытия DockedPanel с помощью жеста или запущенной анимации.

open : bool

Определяет, открыт ли DockedPanel. Изменение значения свойства open приведет к тому, что панель будет открыта или закрыта.

См. также expanded.

[read-only] visibleSize : real

Содержит ширину или высоту видимой части DockedPanel.

Описание методов

hide()

Скрывает DockedPanel.

show()

Отображает DockedPanel.